 Buono sconto 4% su Toner e Cartucce agli utenti AZpoint. SU Iomiricarico.it!!
Ecco
un semplice script per visualizzare nel vostro sito il percorso in
base alla cartella in cui vi trovate.
Lo script è lo stesso
utilizzato in questo sito.
Questo script assume che il vostro
sito sia organizzato in modo che ogni sezione distinta del sito sia
in una cartella diversa e che la struttura di queste cartelle sia
gerarchica per sezione, esempio:
/ Home
|
+-- Informazioni
+-- News
+--+ Sezione1
| +-- Sezione1_01
| +-- Sezione1_02
| +-- Sezione1_03
+--+ Sezione2
| +-- Sezione2_01
| +-- Sezione2_02
| +-- Sezione2_03
+--+ Sezione3
+-- Sezione3_01
+-- Sezione3_02
+-- Sezione3_03
È consigliato che i nomi delle cartelle non contengano
spazi, ed è assunto che la pagine principale di ogni cartella si
chiami index.asp.
Ora veniamo al codice! Creiamo un
file inc_percorsosito.asp in cui inseriamo il seguente codice
e lo mettiamo nella cartella principale del vostro sito: <%
'******************************************************************************
'** Funzione getPercorso **
'******************************************************************************
'** Parametri di Input: **
'** - Percorso che si vuole tracciare **
'** Parametri di Output: **
'** - Stringa contenete il percorso del sito nella forma: **
'** Home >> Cartella1 >> Cartella2 **
'******************************************************************************
Function getPercorso(path)
Dim mappy, i, site
'Imposta il nome del sito (es. http://www.ilmiosito.com)
site="http://"&Request.ServerVariables("HTTP_HOST")
'Reperisce dove inizia la Home nel percorso passato.
If Len(path)>Len(Server.MapPath("/")) Then
path=Right(path, CInt(Len(path)-Len(Server.MapPath("/"))-1))
getPercorso="<A HREF="""&site&"/index.asp"">Home</A>"
Else
path=""
getPercorso="<A HREF="""&site&"/index.asp""><b>Home</b></A>"
End If
'Crea un Array per le cartelle contenute nel percorso dalla Home in poi.
mappy=Split(path, "\", -1, 1)
'Cicla per costruire i vari percorsi.
For i=LBound(mappy) to UBound(mappy)
If i=Ubound(mappy) Then
site=site&"/"&mappy(i)
getPercorso=getPercorso&" » <A HREF="""&site&"/index.asp""><b>"& _
getNomeFromDir(mappy(i))&"</b></A>"
Else
site=site&"/"&mappy(i)
getPercorso=getPercorso&" » <A HREF="""&site&"/index.asp"">"& _
getNomeFromDir(mappy(i))&"</A>"
End If
Next
End Function
'******************************************************************************
'** Funzione getNomeFromDir **
'******************************************************************************
'** Parametri di Input: **
'** - Nome della cartella. **
'** Parametri di Output: **
'** - Nome associato alla cartella. **
'******************************************************************************
Function getNomeFromDir(cartella)
Dim arrCartelle, arrNomi, i
'Array con i nomi delle cartelle.
arrCartelle=Array("cartella1", _
"cartella2", _
"cartella3")
'Array parallelo per associare nomi diversi alle cartelle.
arrNomi=Array("Nome Associato alla Cartella1", _
"Nome Associato alla Cartella2", _
"Nome Associato alla Cartella3")
getNomeFromDir=cartella
'Cicla per verificare se trova una decodifica per la cartella passata.
For i=LBound(arrCartelle) to UBound(arrCartelle)
If UCase(arrCartelle(i))=UCase(cartella) Then
getNomeFromDir=arrNomi(i)
Exit For
End If
Next
End Function
%>Ora per utilizzarlo nelle pagine asp in cui volete
visualizzare il percorso del sito dovrete includere il file creato
precedentemente tramite l'istruzione:
<!--#include virtual="/inc_percorsosito.asp" --> E
nel punto in cui volete visualizzare il percorso basta
scrivere:
<%
Response.Write(getPercorso(Server.MapPath(".")))
%>Scarica l'esempio qui: testpercorso.zip
(1,23Kb)
|
Shopping
