 Buono sconto 4% su Toner e Cartucce agli utenti AZpoint. SU Iomiricarico.it!!
Autore: PritOnLine.it
Utile funzione VBScript che, grazie all'oggetto standard CDONTS.NewMail, consente di spedire
una generica mail tramite pagina ASP: è possibile sia allegare alla mail file binari (ad es. file ZIP)
sia formattare la mail in HTML inviando pure le relative immagini (file GIF o JPG) ivi utilizzate.
<%
Function SendMail(sFrom, sTo, sSub, sBody, iFrm, iPry, sFile, sURL)
Dim objMail, objFile, arrFile, oneFile, imgName, j
On Error Resume Next
Set objMail = Server.CreateObject("CDONTS.NewMail")
If Err.Number = 0 Then
objMail.From = sFrom
objMail.To = sTo
objMail.Cc = ""
objMail.Bcc = ""
objMail.BodyFormat = iFrm
objMail.MailFormat = iFrm
objMail.Importance = iPry
objMail.Subject = sSub
objMail.Body = sBody
Set objFile = CreateObject("Scripting.FileSystemObject")
arrFile = split(sFile, " ")
for j = 0 to uBound(arrFile)
oneFile = Server.MapPath(arrFile(j))
if objFile.FileExists(oneFile) then
objMail.AttachFile oneFile
end if
next
Set objFile = Nothing
if (iFrm = 0) then
Set objFile = CreateObject("Scripting.FileSystemObject")
arrFile = split(sURL, " ")
for j = 0 to uBound(arrFile)
oneFile = Server.MapPath(arrFile(j))
if objFile.FileExists(oneFile) then
imgName = Right(oneFile, len(oneFile)-instrrev(oneFile,"\"))
objMail.AttachURL oneFile, imgName
end if
next
Set objFile = Nothing
end if
objMail.Send
Set objMail = Nothing
SendMail = True
Else
SendMail = False
End If
End Function
%>
Nel corpo della funzione SendMail all'inizio vengono settate tutte quante le proprietà dell'oggetto CDONTS.NewMail
(mittente, destinatario, formato, priorità, titolo e corpo messaggio) poi a seguire vengono allegati i file binari
(solo se essi sono residenti sul server dove si trova la pagina ASP con questa funzione) ed infine vengono allegate
anche le immagini (previa verifica della loro esistenza sul server) utilizzate nella formattazione HTML del testo della mail.
Ma vediamo 2 esempi pratici d'utilizzo della funzione:
1° esempio - spedire una MAIL in formato TXT con allegati 2 file ZIP
<%
iFrm = 1
sFile = "/public/zip/gif08.zip /public/zip/gif09.zip"
if SendMail("mittente@email.it", "destinatario@email.it", _
"Titolo della Mail", "Testo della Mail", iFrm, 1, sFile, "") then
response.write "MAIL spedita alle ore " & Time()
end if
%>
2° esempio - spedire una MAIL in formato HTML con 4 immagini GIF
<%
iFrm = 0
sBody = "<HTML>" &_
"<BODY background='sfondo_welcome.gif'>" &_
"<P> </P>" &_
"<TABLE border=1 cellpadding=8 cellspacing=2>" &_
"<TR><TD><b>BUTTON</b></TD>" &_
"<TD><IMG src='88x31.gif' border=0></TD></TR>" &_
"<TR><TD><b>BANNER</b></TD>" &_
"<TD><IMG src='120x60.gif' border=0></TD></TR>" &_
"<TR><TD><b>BANNER</b></TD>" &_
"<TD><IMG src='468x60.gif' border=0></TD></TR>" &_
"</TABLE>" &_
"<P> </P>" &_
"</BODY>" &_
"</HTML>"
sURL = "/images/sfondo_welcome.gif /banners/88x31.gif " &_
"/banners/120x60.gif /banners/468x60.gif"
if SendMail("mittente@email.it", "destinatario@email.it", _
"Titolo della Mail", sBody, iFrm, 1, "", sURL) then
response.write "MAIL spedita alle ore " & Time()
end if
%>
|
Shopping
